Ecco uno script con le classiche configurazioni di una CPE in modalità NAT Router.

config_cpenatr.src

Editare l'header del file per personalizzare le variabili di configurazione.

# NIMwave CPEWAVE NAT router configuration script
# ver 1.0 (21/04/2010)
# tested on: RouterOS 4.6
#
#Configura le seguenti variabili:
#--------------------------------
:global SSIDNAME "SSID-NAME"
:global CHIAVEWPA "CAMBIAQUESTACHIAVE"
:global PPPOEUSER "username"
:global PPPOEPASS "password"
:global LANIP "192.168.10.1"
:global LANMASK "/24"
:global LANNET "192.168.10.0"
:global DHCPRANGE1 "100"
:global DHCPRANGE2 "200"
#--------------------------------

SSIDNAME: Nome SSID della rete a cui collegarsi
CHIAVEWPA: Chiave WPA2
PPPOEUSER: Nome utente PPPOE
PPPOEPASS: Password PPPOE
LANIP: indirizzo ip da assegnare all'interfaccia ethernet (LAN)
LANMASK: subnet in notazione /XX dell'indirizzo sopra indicato
LANNET: subnet address dell'indirizzo sopra indicato
DHCPRANGE1: estremo inferiore pool DHCP (da abilitare sulla LAN)
DHCPRANGE2: estremo superiore pool DHCP (da abilitare sulla LAN)

Ecco il resto dello script (editate solo se siete utenti esperti :-):

/interface wireless security-profiles
add name="WPA" mode=dynamic-keys authentication-types=wpa2-psk \
unicast-ciphers=aes-ccm group-ciphers=aes-ccm \
wpa2-pre-shared-key=$"CHIAVEWPA" 
#Configura l'interfaccie radio
/interface wireless
set wlan1 mode=station ssid=$"SSIDNAME" country=italy frequency-mode=regulatory-domain \
band=5ghz disabled=no security-profile="WPA" 
#Rimuove l'indirizzo ip di default
/ip address rem [/ip address find interface=ether1]
#Associa un indirizzo ip alla LAN dell'apparato
/ip address add address=($"LANIP" . $"LANMASK") interface=ether1
#interfaccia pppoe
/interface pppoe-client
add add-default-route=yes allow=mschap2 dial-on-demand=no\
disabled=no interface=wlan1 max-mru=1452 max-mtu=1452 mrru=disabled \
name=pppoe-out1 password=$"PPPOEPASS"  profile=default-encryption \
use-peer-dns=yes user=$"PPPOEUSER"
#NAT in uscita dal pppoe
/ip firewall nat
add action=masquerade chain=srcnat disabled=no out-interface=pppoe-out1
# Configurazione DHCP SERVER
:global POOL
:global x
:set x ([:len $LANNET] -1)
:set POOL ([:tostr [:pick $LANNET 0 $x]] )
/ip pool
add name=dhcp_pool1 ranges=($"POOL" . $"DHCPRANGE1" . "-" . $"POOL" . $"DHCPRANGE2")
/ip dhcp-server
add address-pool=dhcp_pool1 authoritative=after-2sec-delay bootp-support=\
static disabled=no interface=ether1 lease-time=3d name=dhcp1
/ip dhcp-server network
add address=($"LANNET" . $"LANMASK") dns-server=$"LANIP" gateway=$"LANIP"
/ip dns
set allow-remote-requests=yes
#--------------------------------